# tcshrc (c) 22.07.2005 Yamagi

# Aliase
alias ls	'/bin/ls -G'
alias su        '/usr/bin/su -l' 

# Standardumask
umask 077

# Autocomplete auf diverse Dinge
complete {man,where,whereis,which} 'p/*/c/'
complete sysctl 'n/*/`sysctl -Na`/'
complete exec 'p/1/c/' 
complete truss 'p/1/c/'
complete -%* 'c/%/j/' # Jobs automatisch füllen
complete {fg,bg,stop} 'c/%/j/ p/1/"(%)"//' 
complete limit 'c/-/"(h)"/ n/*/l/' 
complete unlimit 'c/-/"(h)"/ n/*/l/' 
complete kill 'c/-/S/' 'c/%/j/'
complete {portupgrade,pkg_*} 'p#*#`ls /var/db/pkg`#'
complete kldunload 'p#*#`kldstat | tail +3 | cut -c 29- | sed -e s/\\.ko\$//`#'

# Prompt
set ellipsis                    # Einschränkung der angezeigten Pfadlänge
set promptchars=":>"            # Endzeichen für Nutzer und Root
set prompt="%n@%m:%l %c02%# "   # Das Linke Prompt
set rprompt="[%P]"              # Das rechte Prompt
set prompt2="%R?"               # Prompt Level 2
set prompt3="CORRECT> %B%R%b (y|n|e)?"  # Prompt bei Korrektur

# Pfad
set path = (/usr/opt/texlive/bin/amd64-freebsd /usr/opt/*/bin $path)

# Librarypath
setenv LD_LIBRARY_PATH /usr/opt/lensfun/lib

# Variablen
setenv EDITOR vi
setenv MPD_HOST serioussam@localhost
setenv OOO_FORCE_DESKTOP gnome
setenv P4CONFIG /home/yamagi/.p4config

# History
set history=4096
set histfile=~/.history
set histdup=erase
set savehist=( 4096 merge )
bindkey -k up history-search-backward
bindkey -k down history-search-forward

# Dirstack
set dirsfile=~/.cshdirs 
set savedirs

# Quirk fuer urxvt
if(${?COLORTERM}) then
    if("${COLORTERM}" == "rxvt-xpm" && "${OSTYPE}" == "FreeBSD") then
        /bin/stty status ^t
    endif
endif

# Allgemeines
set nobeep
set inputmode=insert
set autolist=ambiguous
set correct=cmd
set autocorrect
set autoexpand
set symlinks=chase
set listjobs
set listjobs=long
set autolist
set color
set colorcat
set echo_style=bsd
set dunique
set time
set rmstar